TiltedEvolutionScriptFixes/flake.nix at master · absol89/TiltedEvolutionScriptFixes · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
{
  description = "Skyrim Together Reborn linux server build environment";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

  outputs = { self, nixpkgs }:
    let
      systems = [ "x86_64-linux" "aarch64-linux" ];
      forAllSystems = f: nixpkgs.lib.genAttrs systems (system: f nixpkgs.legacyPackages.${system});
    in
    {
      devShells = forAllSystems (pkgs: {
        default = pkgs.mkShell {
          packages = with pkgs; [
            # gcc 15 rejects sol2 v3.3.0, which xmake.lua pins
            gcc14
            gdb
            xmake

            # xmake builds most of its dependencies from source
            cmake
            gnumake
            ninja
            pkg-config
            perl
            python3

            # BuildInfo.h is generated from the git history
            git

            curl
            unzip
          ];

          shellHook = ''
            # Unset environment variables, required for xmake to find
            # the linker/compiler that we provide here
            unset CC
            unset CXX
            unset LD
            unset AR
            unset AS
            unset RANLIB
            unset STRIP
            unset CFLAGS
            unset CXXFLAGS
            unset LDFLAGS

            echo "Linux server build environment loaded, run: xmake config -m releasedbg && xmake"
          '';
        };
      });
    };
}